SUBROUTINE ld_cont_scan(success)

c PURPOSE
c   This subroutine reads in the continuous scan table, using the 
c   routine rd_cont_scan, and puts the data into the appropriate 
c   locations in the common block /rttbls/.  Besides data in the
c   continuous scan table files, a few other tables are computed
c   and also stored in the common block.  
c

      INCLUDE "params.inc"
      INCLUDE "rttbls_cs.cmn"

      LOGICAL success
      CHARACTER*4 ozone_s(0:n_ozone-1)
      INTEGER*2 i
      REAL*4 sza_x(0:n_sza-1), press_x(0:n_press-1)
      REAL*8 radeg      /57.295779513082323/    !deg-rad conversion

c--------------------------------------------------------------------
c read the data from the file.
c
      CALL rd_cont_scan(sza_x, ozone_s, waveln, press_x,
     &                        fs, gg, sb, success)
        IF (.NOT. success) RETURN

d     WRITE(6,91) sza_x
d  91 FORMAT('sza_x: ',3(/(10(f6.1))))
d     WRITE(6,92) ozone_s
d  92 FORMAT('ozone_s:',3(/(10(a4,1x))))

c--------------------------------------------------------------------
c type conversion for sza and 
c precalculate ln(cos(sza)) needed for interpolation.
c
      DO i=0, n_sza-1
        sza(i)=sza_x(i)
        lncossza(i)= log(cos(sza(i)/radeg))
      END DO

c--------------------------------------------------------------------
c extract ozone amount and profile type from the Char*4 data read
c from the file
c
      DO i=0, n_ozone-1
        prftype(i)= ozone_s(i)(1:1)
        read(ozone_s(i)(2:4),1) ozone(i)
      END DO

c--------------------------------------------------------------------
c type conversion for pressure
c
      press(0)=press_x(0)
      press(1)=press_x(1)
c--------------------------------------------------------------------
c ix___lat variables indicate index of first element of ozone tables
c for each of the profile types.
c
      ixlowlat=0
      ixmidlat=0
      ixhighlat=0

      DO i= n_ozone-1, 0, -1
        IF (prftype(i) .EQ. 'L') ixlowlat= i
        IF (prftype(i) .EQ. 'M') ixmidlat= i
        IF (prftype(i) .EQ. 'H') ixhighlat= i
      END DO

c--------------------------------------------------------------------
c convert wavelengths from \AAngstrom to nm
c
      DO i=0, n_waveln-1
        waveln(i)= waveln(i)/10.d0
      END DO

d     WRITE(6,93)(waveln(j),j=0,4),(waveln(j),j=n_waveln-5,n_waveln-1)
d  93 FORMAT('first 5 wavelengths:'/5f12.3/'last 5 wavelengths'/
d    &       5f12.3)

      success=.TRUE.
      RETURN
    1 FORMAT(F3)

      END