pro plot_sat_points,dd,dy19,takeoff_gmt,lat,lon,sat_col,local_to_gmt,times=times,sat_char=sat_char,noarrow=noarrow,$
   print_data=print_data,aztop=aztop
;
;  this routine plots the satellite points on a map
;  dd is the array of day1900 days +fractions which have the satellite data
;  dy19 is the plotting day
;  lat is the satellit latitudes
;  lon is the satellite longitudes
;  sat_col is the color of the satellite point - not used now
;  local_to_gmt is the offset from gmt is hours (local time=gmt+local_to_gmt)
;  times is the array of satellite times found by the program (local)
;  sat_char is a character printed in front of the plotted times
;  print is a keyword that prints the selected points
;  
     n=where(dd gt dy19+(takeoff_gmt-12.)/24. and dd lt dy19+(takeoff_gmt+12.)/24.)
     if n(0) ge 0 then begin
       symb,10,/fill 
       s=size(lat)
       if s(0) eq 2 then oplot,lon(1,n),lat(1,n),psym=8,col=sat_col else $
            oplot,lon(n),lat(n),psym=8,col=sat_col
       if not keyword_set(noarrow) then $
       if s(0) eq 2 then for js=0,n_elements(n)-1 do arrow,lon(0,n(js)),lat(0,n(js)),lon(2,n(js)),lat(2,n(js)),color=sat_col,/data
       times=[0.]
       if keyword_set(print_data) then begin
       
       print,'Satellite Overpass Points'
       print,sat_char+'        Lon               Lat   DD:HH:MM (GMT)   Azimuth   '
       endif
        if n_elements(aztop) eq 0 then azt=fltarr(n_elements(n)) else azt=aztop(n)
       for ji=0,n_elements(n)-1 do begin
          frac=dd(n(ji))-long(dd(n(ji)))
          drate=strtrim(date1900(dd(n(ji)),/fullyear),2)
	  ddate=strmid(drate,6,2)
          hours=fix(24*frac)
          times=[times,24.*frac]
          min=fix((frac*1440.-hours*60.))
          if min le 9 then strmin='0'+string(min,format='(I1)') else strmin=string(min,format='(i2)')
          if hours le 9 then strhr='0'+string(hours,format='(I1)') else strhr=string(hours,format='(i2)')
          if s(0) eq 2 then xyouts,lon(1,n(ji)),lat(1,n(ji)),' '+sat_char+ddate+':'+strhr+':'+strmin,color=sat_col,/data,size=0.9,noclip=0 $
              else xyouts,lon(n(ji)),lat(n(ji)),' '+sat_char+ddate+':'+strhr+':'+strmin,color=sat_col,/data,size=0.9,noclip=0
              if keyword_set(print_data) then begin
              if s(0) eq 2 then print,lon(1,n(ji)),lat(1,n(ji)),' '+sat_char+ddate+':'+strhr+':'+strmin else $
                 print,lon(n(ji)),lat(n(ji)),' '+sat_char+ddate+':'+strhr+':'+strmin,azt(ji)
              endif
          endfor
          
          times=times(1:*)
          endif


return
end